技术咨询
代买器件
商务客服
研发客服1. S2C2440 的时钟是通过MPLL锁相环环来进行倍频的 其中公式为
在S2C2440里面有三种时钟 1： FLCK 这个是内核的时钟最大可以到400Mhz
2. HLCK 高速时钟 这个是提供给内部资源的时钟最大为136Mhz
3. Pclk 这个是外设的时钟 最大是68Mhz
注意： 所有的时钟都是有FLCK分频得来
下面我们要做的是如何在内核时钟最大的时候400Mhz 的时候 分频给Hclk 100Mhz 和外设时钟68Mhz
上图的寄存器是为ARM提供上电延时的时钟延时 一般都是取默认值
上图的寄存器是从FCLK分频： 其中HDIVN我们选择 10 PDIVN 我们选择HLCK/2 即1 100MZH/2
这段代码需要加载到汇编语言中
随后就是倍频寄存器 图如下
我们利用已经给好的数组算出就好。
下面是代码
.text
.global _start
_start:
/* 关闭看门狗 */
ldr r0, =0x53000000
ldr r1, =0
str r1, [r0]
/* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */
/* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
ldr r0, =0x4C000000
ldr r1, =0xFFFFFFFF
str r1, [r0]
/* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8 */
ldr r0, =0x4C000014
ldr r1, =0x5
str r1, [r0]
/* 设置CPU工作于异步模式 */
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000 //R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0
/* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0)
* m = MDIV+8 = 92+8=100
* p = PDIV+2 = 1+2 = 3
* s = SDIV = 1
* FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
*/
ldr r0, =0x4C000004
ldr r1, =(92<<12)|(1<<4)|(1<<0)
str r1, [r0]
/* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
* 然后CPU工作于新的频率FCLK
*/
/* 设置内存: sp 栈 */
/* 分辨是nor/nand启动
* 写0到0地址, 再读出来
* 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
* 否则就是nor启动
*/
mov r1, #0
ldr r0, [r1] /* 读出原来的值备份 */
str r1, [r1] /* 0->[0] */
ldr r2, [r1] /* r2=[0] */
cmp r1, r2 /* r1==r2? 如果相等表示是NAND启动 */
ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
moveq sp, #4096 /* nand启动 */
streq r0, [r1] /* 恢复原来的值 */
bl main
halt:
b halt
相关文章
